Script.rpy

Материал из Ren'Py Wiki
Перейти к навигации Перейти к поиску

В данном разделе представлен основной script.rpy файл визуальной новеллы «Вопрос». С полным кодом «Вопроса» можно ознакомиться в Ren'Py Launcher или посетив раздел the_question на сайте github.com.

# Определите персонажей, используемых в этой игре.
define s = Character('Сильвия', color="#c8ffc8")
define m = Character('Я', color="#c8c8ff")

# Это переменная, которая принимает значение True, если вы сравнили VN с книгой
# и принимает значение False при ином выборе.
default book = False

# Игра начинается здесь.
label start:

    # Сначала воспроизводится музыка.
    play music "illurock.ogg"

    scene bg lecturehall
    with fade

    "Только тогда, когда я слышу звуки движения ног и шуршание убираемых материалов, понимаю, что лекция окончена."

    "Лекции профессора Эйлин обычно вызывают интерес, но сегодня я просто не смог на них сосредоточиться."

    "У меня было много других мыслей... Мыслей, приводящих к вопросу."

    "Этот вопрос я хотел бы задать кое-кому."

    scene bg uni
    with fade

    "Когда мы вышли из университета, я сразу заметил её."

    show sylvie green normal
    with dissolve

    "Я знаю Сильвию с детства. Девушка с большим сердцем и мой хороший друг."

    "Но недавно... Я почувствовал, что хочу чего-то большего."

    "Больше, чем просто разговаривать, больше, чем просто ходить вместе домой после занятий."

    menu:

        "Как только наши взгляды встречаются, я решаю..."

        "Спросить её прямо сейчас.":

            jump rightaway

        "Спросить её позже.":

            jump later


label rightaway:

    show sylvie green smile

    s "Привет! Как прошёл урок?"

    m "Хорошо..."

    "У меня язык не поворачивается признаться, что всю лекцию профессора Эйлин я витал в своих мыслях."

    m "Идешь домой? Не хочешь прогуляться со мной?"

    s "Конечно!"

    scene bg meadow
    with fade

    "Вскоре мы дошли до луга, расположенного недалеко от района, где мы оба живем."

    "Это живописный вид, к которому я привык. Осень здесь особенно прекрасна."

    "Когда мы были детьми, мы часто играли на этих лугах, так что места здесь переполнены воспоминаниями."

    m "Эй... Эммм..."

    show sylvie green smile
    with dissolve

    "Она обернулась и улыбнулась. Она выглядит так приветливо, что я чувствую, что избавляюсь от нервозности."

    "Я спрошу её..."

    m "Эмм... Ты согласишься..."

    m "Ты станешь художником для моей визуальной новеллы?"

    show sylvie green surprised

    "Молчание."

    "Она выглядит настолько шокированной, что я начинаю бояться худшего. Но потом..."

    show sylvie green smile

    menu:

        s "Конечно, но что такое \"визуальная новелла?\""

        "Это видеоигра.":
            jump game

        "Это интерактивная книга.":
            jump book

label game:

    m "Это своего рода видеоигра, в которую можно играть на компьютере или консоли."

    m "Визуальные новеллы рассказывают историю с помощью изображений и музыки."

    m "Иногда ты имеешь возможность сделать выборы, которые повлияют на исход истории."

    s "Так это как в книгах выбери-своё-приключение?"

    m "Именно! У меня много различных идей, которые, на мой взгляд, сработают."

    m "И я подумал, что ты могла бы мне помочь... так как я знаю, как ты любишь рисовать."

    m "Мне будет сложно создать визуальную новеллу в одиночку."


    show sylvie green normal

    s "Ну, конечно! Я попробую. Надеюсь, что не разочарую тебя."

    m "Ты не можешь разочаровать меня, тебе это известно, Сильвия."

    jump marry

label book:

    $ book = True

    m "Это как интерактивная книга, которую можно читать на компьютере или консоли."

    show sylvie green surprised

    s "Интерактивная?"

    m "Ты можешь делать выборы, которые приведут к различным событиям и концовкам в истории."

    s "А причём здесь \"визуальная\" часть?"

    m "В визуальных новеллах есть изображения и даже музыка, звуковые эффекты, а иногда и озвучка, которая воспроизводится вместе с текстом."

    show sylvie green smile

    s "Ясно! Это определенно здорово звучит. Я и сама давным-давно создавала веб-комиксы, так что у меня много идей для сюжета."

    m "Это же здорово! Так... хочешь поработать со мной в качестве художника?"

    s "С удовольствием!"

    jump marry

label marry:

    scene black
    with dissolve

    "И так мы стали командой по разработке визуальных новелл."

    scene bg club
    with dissolve

    "На протяжении многих лет мы разрабатывали игр и это было очень увлекательно."

    if book:
        "Наша первая игра основана на одной из идей Сильвии, но потом я тоже придумывал свои истории."

    "Мы по очереди придумываем истории и персонажей и поддерживаем друг друга, чтобы создать некоторые большие игры!"

    "И однажды..."

    show sylvie blue normal
    with dissolve

    s "Эй..."

    m "Да?"

    show sylvie blue giggle

    s "Женись на мне!"
    m "Что? С чего бы это вдруг?"

    show sylvie blue surprised

    s "Ну же, как давно мы встречаемся?"

    m "Некоторое время..."

    show sylvie blue smile

    s "Последние несколько лет мы вместе делаем визуальные новеллы, проводя время вместе, помогая друг другу..."

    s "Я уже довольно хорошо тебя знаю и забочусь о тебе лучше, чем кто-либо другой. И я думаю, что то же верно и в отношении тебя, верно?"

    m "Сильвия..."

    show sylvie blue giggle

    s "Но я знаю, что ты такой нерешительный. Если бы я молчала об этом, то кто знает, когда бы ты сделал предложение?"

    show sylvie blue normal

    s "Так ты женишься на мне?"

    m "Конечно женюсь. Я действительно собирался предложить, честно!"

    s "Я знаю, я знаю."

    m "Полагаю... Я слишком волновался о времени. Я хотела задать правильный вопрос в нужное время."

    show sylvie blue giggle

    s "Ты слишком переживаешь. Если бы только это была визуальная новелла и я бы могла выбрать вариант, чтобы дать тебе больше смелости!"

    scene black
    with dissolve

    "И мы поженились вскоре после этого."

    "Наша команда по разработке визуальных новелл существует даже после того, как мы поженились... И я стараюсь быть более решительным."

    "Вместе мы живем счастливо даже сейчас."

    "{b}Хорошая концовка{/b}."

    return

label later:

    "Я не могу собраться с духом, чтобы задать вопрос прямо сейчас. Взглотнув, я решил спросить её позже."

    scene black
    with dissolve

    "Но был таким нерешительным."

    "Я не смог спросить её в тот день и, в конечном итоге, никогда не наберусь храбрости, чтобы спросить."
    "Думаю, теперь я никогда не узнаю ответа на свой вопрос..."

    "{b}Плохая концовка{/b}."

    return

Источник[править | править код]

Статья "Script of The Question" на английском языке


Краткое руководство Вернуться к началу статьи